ノベルゲーム『百花の街をさまよう』トゥルールート原案

macro.ks

;マクロ定義

;【選択肢ボタン関連】

;背景や色の一括変更ができるよう、マクロへ。

;普通のボタン

;[select storage="" target="" text=""]

[macro name="select1"]

[glink storage=%storage target=%target text=%text color=black x="260" width="400" y="100" clickse="kachi.ogg]

[endmacro]

[macro name="select2"]

[glink storage=%storage target=%target text=%text color=black x="260" width="400" y="240" clickse="kachi.ogg]

[endmacro]

;トゥルーガイド機能つきボタン

[macro name="select1_true"]

[if exp="sf.trueguide"]

[glink storage=%storage target=%target text=%text color=rosy x="260" width="400" y="100" clickse="kachi.ogg]

[else]

[glink storage=%storage target=%target text=%text color=black x="260" width="400" y="100" clickse="kachi.ogg]

[endif]

[endmacro]

[macro name="select2_true"]

[if exp="sf.trueguide"]

[glink storage=%storage target=%target text=%text color=rosy x="260" width="400" y="240" clickse="kachi.ogg]

[else]

[glink storage=%storage target=%target text=%text color=black x="260" width="400" y="240" clickse="kachi.ogg]

[endif]

[endmacro]

;↑あとでもっといい方法思いついたけど直せなかった。true選択肢かどうかも%で引いて判定すればよかったんだ

;【メッセージウィンドウ関連】

;name領域定義

[ptext name="chara_name_area" layer=message0 width="200" color=white x=40 y=430 size=26]

[chara_config ptext="chara_name_area"]

[macro name="message_full"]

[position layer="message0" left=20 top=40 width=920 height=580 page=fore visible=true]

@layopt layer=message0 visible=true

[endmacro]

[macro name="message_talk"]

[position layer="message0" left=20 top=410 width=920 height=200 page=fore visible=true　page=fore margint="50" marginl="40" marginr="70" marginb="50"]

@layopt layer=message0 visible=true

[endmacro]

[macro name="fadeout_message"]

#

[hidemenubutton]

;------------keyframe の定義

[keyframe name="fadeout"]

[frame p=0% opacity=0.75]

[frame p=100% opacity=0]

[endkeyframe]

;---------アニメーションの実行

[kanim layer="message0" keyframe="fadeout" time=%time|800 ]

[wa]

[endmacro]

[macro name="fadein_message"]

;------------keyframe の定義

[keyframe name="fadein"]

[frame p=0% opacity=0]

[frame p=100% opacity=0.75]

[endkeyframe]

;---------アニメーションの実行

[kanim layer="message0" keyframe="fadein" time=%time|800 ]

[wa]

[showmenubutton]

[endmacro]

;改ページ待ち画像

[macro name="turn"]

[graph storage="page_turn.png"]

[l][cm]

[endmacro]

;【氏名表示関連】

;ミノリの名前を知ってるか否か

[macro name="minori"]

[if exp="f.minori"]

#minori

[else]

#minori_x

[endif]

[endmacro]

;【フラグ管理関連】

;dayend既読リセット

;日付変更カットイン内に埋め込み

[macro name="reset_read"]

[eval exp="f.done_mag = false"]

[eval exp="f.done_wis = false"]

[eval exp="f.done_cam = false"]

[eval exp="f.done_che = false"]

[eval exp="f.done_hyd = false"]

[eval exp="f.done_momi = false"]

[endmacro]

;【エフェクト】

;日付変更カットイン

;[day_change text="" next="next place .jpg"]

[macro name="day_change"]

;-----前日の既読フラグを削除

[reset_read]

;-----演出

[hidemenubutton]

@layopt layer=message0 visible=false

[bg storage="black.jpg" time=600]

@layopt layer=0 visible=true

[mtext text=%text in_effect="fadeInLeft" out_effect="fadeOutRight" x=430 y=200 size=30]

@layopt layer=0 visible=false

[bg storage=%next time=1000]

[showmenubutton]

[endmacro]

;エンディングネーム表示

;[ending_name text="エンディング名"]

[macro name="ending_name"]

#

[cancelskip]

[layopt layer="message" visible=false]

[wait time=2000]

[layopt layer=1 visible=true]

[ptext layer=1 text="%text" size=50 x=90 y=300 color=snow ]

@jump storage="endroll.ks"

[endmacro]

;エンドロール待機

[macro name="waiting"]

[wait time=3500]

[cm]

[endmacro]

;【マップメニュー関連】

[macro name="fadein_map"]

;------------keyframe の定義

[keyframe name="fadein"]

[frame p=0% opacity=0]

[frame p=100% opacity=0.75]

[endkeyframe]

;---------アニメーションの実行

[kanim layer="message0" keyframe="fadein" time="800" ]

[wa]

[endmacro]

[macro name="map_menu"]

;---背景設定

[if exp="f.trueroot = true"]

[bg storage="road_true.JPG" wait=true time=800]

[else]

[bg storage="pinkroad.JPG" wait=true time=800]

[endif]

;---メニュー下地

[message_full]

[fadein_map]

;[fadein_message]

;---クリック待ち画像を消しとばす

[glyph fix=true left=1000 top=1000 ]

;---メッセージをセンタリング

[iscript]

$('.message_inner').css('text-align', 'center');

[endscript]

;---インターフェース

[delay speed=100]

どこへ行こう？[r]

[resetdelay]

[r]

[r]

[endmacro]

;マップから移動する全てのシナリオ冒頭に置く

;[quest_phase next="next place.jpg"]

[macro name="quest_phase"]

;---各種リセット

[cm]

[glyph fix=false]

[resetfont]

[iscript]

$('.message_inner').css('text-align','left');

[endscript]

;---舞台セットアップ

@layopt layer=message0 visible=false

[bg storage=%next wait=true]

[showmenubutton]

[endmacro]

;シナリオからマップに戻る

[macro name="to_map"]

;---メッセージウィンドウ撤退

[fadeout_message]

@jump storage="system/to_map.ks"

[endmacro]

;EOF